123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174 |
- /* ====================================================================
- Licensed to the Apache Software Foundation (ASF) under one or more
- contributor license agreements. See the NOTICE file distributed with
- this work for additional information regarding copyright ownership.
- The ASF licenses this file to You under the Apache License, Version 2.0
- (the "License"); you may not use this file except in compliance with
- the License. You may obtain a copy of the License at
-
- http://www.apache.org/licenses/LICENSE-2.0
-
- Unless required by applicable law or agreed to in writing, software
- distributed under the License is distributed on an "AS IS" BASIS,
- WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
- See the License for the specific language governing permissions and
- limitations under the License.
- ==================================================================== */
-
- import java.util.regex.Pattern
-
- configurations {
- tests
- }
-
- sourceSets {
- main {
- if (JavaVersion.current() != JavaVersion.VERSION_1_8) {
- output.dir(JAVA9_OUT, builtBy: 'cacheJava9')
- }
- }
- test {
- if (JavaVersion.current() != JavaVersion.VERSION_1_8) {
- output.dir(TEST9_OUT, builtBy: 'cacheTest9')
- }
- }
- }
-
- dependencies {
- api 'org.apache.ant:ant:1.10.9'
-
- api project(':poi-ooxml')
- api project(':poi-scratchpad')
- api project(path: ':poi-ooxml', configuration: 'archives')
- api project(path: ':poi-scratchpad', configuration: 'archives')
-
- testImplementation project(path: ':poi-ooxml-lite-agent', configuration: 'archives')
- testImplementation project(path: ':poi', configuration: 'tests')
- testImplementation project(path: ':poi-ooxml', configuration: 'tests')
- testImplementation project(path: ':poi-scratchpad', configuration: 'tests')
- testImplementation 'com.google.guava:guava:30.0-jre'
- testImplementation 'org.apache.logging.log4j:log4j-slf4j-impl:2.14.1'
- }
-
- final String MODULE_NAME = 'org.apache.poi.excelant'
- final Pattern MODULE_NOT_REGEX = ~'((poi|poi-ooxml|poi-scratchpad)[/\\\\][^/\\\\]+$|batik-script)'
- final Pattern MODULE_REGEX = ~'\\.jar$'
- final List MAIN_MODULE_PATH = sourceSets.main.runtimeClasspath.findAll{ it.path =~ MODULE_REGEX }.collect{ it.parent }.unique()
- final List TEST_MODULE_PATH = sourceSets.test.runtimeClasspath.findAll{ it.path =~ MODULE_REGEX && !(it.path =~ MODULE_NOT_REGEX) }.collect{ it.parent }.unique()
-
- final String OOXML_LITE_AGENT = "../build/dist/maven/poi-ooxml-lite-agent/poi-ooxml-lite-agent-${project.version}.jar"
- final String OOXML_LITE_REPORT = '../build/ooxml-lite-report'
- final String OOXML_LITE_JAR = "../build/dist/maven/poi-ooxml-lite/poi-ooxml-lite-${project.version}.jar"
- final String OOXML_LITE_INCLUDES = "^(com/microsoft/schemas|org/(etsi|openxmlformats|w3/)|org/apache/poi/schemas)"
-
- task compileJava9(type: JavaCompile) {
- dependsOn 'compileJava', ':poi-ooxml:jar', ':poi-scratchpad:jar'
-
- sourceCompatibility = 9
- targetCompatibility = 9
- destinationDirectory = file(JAVA9_OUT + VERSIONS9)
- source = file(JAVA9_SRC)
- classpath = files()
- options.compilerArgs = [
- '--patch-module', "${MODULE_NAME}=${sourceSets.main.output.classesDirs.asPath}",
- '--module-path', files(MAIN_MODULE_PATH).asPath
- ]
- }
-
- task cacheJava9(type: Copy) {
- dependsOn 'compileJava9'
-
- from(file(JAVA9_OUT + VERSIONS9))
- into(JAVA9_SRC)
- }
-
- task compileTest9(type: JavaCompile) {
- dependsOn 'compileTestJava', ':poi-ooxml:jar', ':poi-scratchpad:jar'
-
- sourceCompatibility = 9
- targetCompatibility = 9
- destinationDirectory = file(TEST9_OUT + VERSIONS9)
- source = file(TEST9_SRC)
- options.compilerArgs = [
- '--patch-module', "${MODULE_NAME}=${(sourceSets.main.output.classesDirs + sourceSets.test.output.classesDirs).asPath}",
- '--module-path', files(TEST_MODULE_PATH).asPath
- ]
- classpath = files()
- }
-
-
- task cacheTest9(type: Copy) {
- dependsOn 'compileTest9'
-
- from(file(TEST9_OUT + VERSIONS9))
- into(TEST9_SRC)
- }
-
- jar {
- dependsOn cacheJava9
-
- destinationDirectory = file("../build/dist/maven/${project.archivesBaseName}")
-
- if (JavaVersion.current() == JavaVersion.VERSION_1_8) {
- into('META-INF/versions/9') {
- from JAVA9_SRC include '*.class'
- }
- }
-
- manifest {
- attributes('Automatic-Module-Name': MODULE_NAME, 'Multi-Release': 'true')
- }
- }
-
- // Create a separate jar for test-code to depend on it in other projects
- // See http://stackoverflow.com/questions/5144325/gradle-test-dependency
- task testJar(type: Jar, dependsOn: [ testClasses, cacheTest9 ] ) {
- destinationDirectory = file("../build/dist/maven/${project.archivesBaseName}-tests")
-
- classifier 'tests'
- // ignore second module-info.class from main
- duplicatesStrategy = 'exclude'
-
- if (JavaVersion.current() == JavaVersion.VERSION_1_8) {
- into('META-INF/versions/9') {
- from TEST9_SRC include '*.class'
- }
- }
-
- from sourceSets.test.output + sourceSets.main.output
-
- manifest {
- attributes('Automatic-Module-Name': MODULE_NAME, 'Multi-Release': 'true')
- }
- }
-
- artifacts {
- tests testJar
- }
-
- test {
- dependsOn { testJar }
-
- doFirst {
- jvmArgs += [
- "-javaagent:${OOXML_LITE_AGENT}=${OOXML_LITE_REPORT}|${OOXML_LITE_INCLUDES}",
- ]
- if (JavaVersion.current() != JavaVersion.VERSION_1_8) {
- jvmArgs += [
- '--add-modules', MODULE_NAME,
- '--module-path', '../build/dist/maven/poi-excelant-tests' + File.pathSeparator + files(TEST_MODULE_PATH).asPath,
- ]
- }
- }
- }
-
- publishing {
- publications {
- POI(MavenPublication) {
- pom {
- name = 'Apache POI - ExcelAnt'
- description = 'Apache POI - Java API To Access Microsoft Format Files'
- }
- }
- }
- }
|