sonarqube/server/sonar-server-common/build.gradle

description = 'Code shared between the Web Server and the Compute Engine'

sonarqube {
  properties {
    property 'sonar.projectName', "${projectTitle} :: Server :: Common"
  }
}

configurations {
  tests

  testCompile.extendsFrom tests
}

dependencies {
  // please keep the list grouped by configuration and ordered by name

  compile 'org.apache.commons:commons-email'
  compile 'com.google.guava:guava'
  compile 'org.slf4j:slf4j-api'
  compile 'com.squareup.okhttp3:okhttp'
  compile 'org.elasticsearch.client:transport'
  compile project(':server:sonar-db-dao')
  compile project(':sonar-core')
  compile project(':sonar-markdown')
  compile project(':sonar-ws')

  compileOnly project(path: ':sonar-plugin-api')
  compileOnly project(path: ':server:sonar-process')

  compileOnly 'com.google.code.findbugs:jsr305'

  // "tests" dependencies are pulled by other modules which depends on "tests" configuration, "testCompile" are not pulled
  tests 'org.codelibs.elasticsearch.module:analysis-common'
  tests 'org.elasticsearch:mocksocket'

  testCompile 'ch.qos.logback:logback-core'
  testCompile 'com.google.code.findbugs:jsr305'
  testCompile 'com.h2database:h2'
  testCompile 'com.squareup.okhttp3:mockwebserver'
  testCompile 'com.tngtech.java:junit-dataprovider'
  testCompile 'junit:junit'
  testCompile 'org.apache.logging.log4j:log4j-api'
  testCompile 'org.apache.logging.log4j:log4j-core'
  testCompile 'org.assertj:assertj-core'
  testCompile 'org.assertj:assertj-guava'
  testCompile 'org.mockito:mockito-core'
  testCompile project(':server:sonar-db-testing')
}

task testJar(type: Jar) {
  classifier = 'tests'
  from sourceSets.test.output
}

artifacts {
  tests testJar
}