sonarqube/plugins/sonar-education-plugin/build.gradle

configurations {
    testImplementation.extendsFrom(compileOnlyApi)
}

dependencies {
    compileOnlyApi 'org.sonarsource.api.plugin:sonar-plugin-api'

    testImplementation 'junit:junit'
    testImplementation 'org.assertj:assertj-core'
    testImplementation 'org.mockito:mockito-core'
    testImplementation project(':sonar-plugin-api-impl')
}

jar {
    manifest {
        attributes(
                'Plugin-Key': 'education',
                'Plugin-Version': project.version,
                'Plugin-Class': 'org.sonar.education.EducationPlugin',
                'Plugin-ChildFirstClassLoader': 'false',
                'Sonar-Version': project.version,
                'SonarLint-Supported': 'true',
                'Plugin-Name': 'Education'
        )
    }
    into('META-INF/lib') {
        from configurations.compileClasspath
    }
}

artifactoryPublish.skip = false

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
            if (release) {
                artifact sourcesJar
                artifact javadocJar
            }
        }
    }
}