123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370 |
- import groovy.json.JsonOutput
- import groovy.json.JsonSlurper
- import org.apache.tools.ant.filters.ReplaceTokens
-
- plugins {
- id "com.github.hierynomus.license-report"
- id "com.github.johnrengelman.shadow"
- id "de.undercouch.download"
- id "org.cyclonedx.bom"
- }
-
- sonar {
- properties {
- property 'sonar.projectName', "${projectTitle} :: Application"
- }
- }
-
- configurations {
- zip
- scanner
- web
- shutdowner
- jdbc_mssql {
- transitive = false
- }
- jdbc_postgresql {
- transitive = false
- }
- jdbc_h2 {
- transitive = false
- }
- bundledPlugin {
- transitive = false
- }
- bundledPlugin_deps {
- extendsFrom bundledPlugin
- transitive = true
- }
- appLicenses.extendsFrom(api, web, scanner, jdbc_mssql, jdbc_postgresql, jdbc_h2, bundledPlugin_deps)
- cyclonedx
- }
-
- jar.enabled = false
- shadowJar {
- archiveBaseName = 'sonar-application'
- archiveClassifier = null
- mergeServiceFiles()
- manifest {
- attributes('Main-Class': 'org.sonar.application.App')
- }
- }
-
- dependencies {
- // please keep list ordered
- api 'org.slf4j:slf4j-api'
-
- api 'org.elasticsearch.client:elasticsearch-rest-high-level-client'
- api 'org.sonarsource.api.plugin:sonar-plugin-api'
- api project(':server:sonar-ce')
- api project(':server:sonar-main')
- api project(':server:sonar-process')
- api project(':server:sonar-webserver')
- api project(':sonar-core')
- api project(':sonar-plugin-api-impl')
-
- compileOnlyApi 'com.google.code.findbugs:jsr305'
-
- scanner project(path: ':sonar-scanner-engine-shaded', configuration: 'shadow')
- cyclonedx project(path: ':sonar-scanner-engine-shaded')
- web project(':server:sonar-web')
- shutdowner project(':sonar-shutdowner')
-
- jdbc_h2 'com.h2database:h2'
- jdbc_mssql 'com.microsoft.sqlserver:mssql-jdbc'
- jdbc_postgresql 'org.postgresql:postgresql'
- }
-
- // declare dependencies in configuration bundledPlugin to be packaged in lib/extensions
- apply from: 'bundled_plugins.gradle'
-
- //verify if sonar.properties files does not have any external input
- task verifySonarProperties(type: Verify) {
- def propertiesFile = file('src/main/assembly/conf/sonar.properties')
- propertiesFile.withReader { reader ->
- def line
- while ((line = reader.readLine()) != null) {
- if (!line.startsWith('#') && !line.isEmpty()) {
- throw new GradleException('sonar.properties file by default must not provide any user configuration.')
- }
- }
- }
- }
-
- task verifyElasticSearchDownload(type: Verify) {
- src new File(buildDir, "$elasticsearchDownloadUrlFile")
- algorithm 'SHA-512'
- checksum elasticsearchDownloadSha512
- }
-
- task downloadElasticSearch(type: Download) {
- def artifactoryUsername = System.env.'ARTIFACTORY_PRIVATE_USERNAME' ?: (project.hasProperty('artifactoryUsername') ? project.getProperty('artifactoryUsername') : '')
- def artifactoryPassword = System.env.'ARTIFACTORY_PRIVATE_PASSWORD' ?: (project.hasProperty('artifactoryPassword') ? project.getProperty('artifactoryPassword') : '')
- if (artifactoryUsername && artifactoryPassword) {
- src "$elasticsearchDownloadRepoxUrlPath$elasticsearchDownloadUrlFile"
- username artifactoryUsername
- password artifactoryPassword
- } else {
- src "$elasticsearchDownloadUrlPath$elasticsearchDownloadUrlFile"
- }
- dest "$buildDir/$elasticsearchDownloadUrlFile"
- onlyIfModified true
- finalizedBy verifyElasticSearchDownload
- }
-
- downloadLicenses {
- dependencyConfiguration = 'appLicenses'
- }
-
- task zip(type: Zip, dependsOn: [configurations.compileClasspath, downloadElasticSearch, verifyElasticSearchDownload]) {
- duplicatesStrategy DuplicatesStrategy.EXCLUDE
- def archiveDir = "sonarqube-$project.version"
-
- if(release) {
- dependsOn tasks.downloadLicenses
- into("${archiveDir}/") {
- from(tasks.downloadLicenses.outputs) {
- include 'dependency-license.json'
- eachFile { jsonFile ->
- def json = new JsonSlurper().parse(jsonFile.file)
- json.dependencies.each { dependency ->
- if (dependency.licenses.size() > 1) {
- def idx = dependency.licenses.findIndexOf { it.name == "Elastic License 2.0" }
- if (idx >= 0) {
- dependency.licenses = [dependency.licenses[idx]]
- }
- }
- }
- json.dependencies.sort { it.name }
- def jsonText = JsonOutput.toJson(json)
- jsonFile.file.text = JsonOutput.prettyPrint(jsonText)
- }
- }
- }
- }
-
- into("${archiveDir}/") {
- from(file('src/main/assembly')) {
- exclude 'conf/sonar.properties'
- exclude 'bin/windows-x86-64/lib/SonarServiceWrapperTemplate.xml'
- exclude 'bin/windows-x86-64/StartSonar.bat'
- exclude 'elasticsearch-patch'
- exclude 'bin/linux-x86-64/sonar.sh'
- exclude 'bin/macosx-universal-64/sonar.sh'
- }
- }
-
-
- from(tarTree(downloadElasticSearch.dest)) {
- eachFile { fcd ->
- def path = fcd.relativePath.segments - fcd.relativeSourcePath.segments + fcd.relativeSourcePath.segments.drop(1)
- fcd.relativePath = new RelativePath(true, *path)
- }
- into("${archiveDir}/elasticsearch")
- filesMatching('**/bin/elasticsearch-env') {
- // to avoid warning logs
- filter { line -> line.replaceAll('echo "warning: no-jdk distributions.*', ':') }
- }
- // elasticsearch script will be replaced by patched version below
- exclude '**/bin/elasticsearch'
- exclude '**/bin/elasticsearch-certgen'
- exclude '**/bin/elasticsearch-certutil'
- exclude '**/bin/elasticsearch-cli'
- exclude '**/bin/elasticsearch-croneval'
- exclude '**/bin/elasticsearch-geoip'
- exclude '**/bin/elasticsearch-keystore'
- exclude '**/bin/elasticsearch-migrate'
- exclude '**/bin/elasticsearch-node'
- exclude '**/bin/elasticsearch-plugin'
- exclude '**/bin/elasticsearch-saml-metadata'
- exclude '**/bin/elasticsearch-service-tokens'
- exclude '**/bin/elasticsearch-setup-passwords'
- exclude '**/bin/elasticsearch-shard'
- exclude '**/bin/elasticsearch-sql-cli*'
- exclude '**/bin/elasticsearch-syskeygen'
- exclude '**/bin/elasticsearch-users'
- exclude '**/bin/x-pack-env'
- exclude '**/bin/x-pack-security-env'
- exclude '**/bin/x-pack-watcher-env'
- exclude '**/jdk/**'
- exclude '**/lib/tools/**'
- exclude '**/modules/aggs-matrix-stats/**'
- exclude '**/modules/constant-keyword/**'
- exclude '**/modules/frozen-indices/**'
- exclude '**/modules/ingest-common/**'
- exclude '**/modules/ingest-geoip/**'
- exclude '**/modules/ingest-user-agent/**'
- exclude '**/modules/kibana/**'
- exclude '**/modules/lang-expression/**'
- exclude '**/modules/lang-mustache/**'
- exclude '**/modules/legacy-geo/**'
- exclude '**/modules/mapper-extras/**'
- exclude '**/modules/mapper-version/**'
- exclude '**/modules/percolator/**'
- exclude '**/modules/rank-eval/**'
- exclude '**/modules/repositories-metering-api/**'
- exclude '**/modules/repository-encrypted/**'
- exclude '**/modules/repository-url/**'
- exclude '**/modules/runtime-fields-common/**'
- exclude '**/modules/search-business-rules/**'
- exclude '**/modules/searchable-snapshots/**'
- exclude '**/modules/snapshot-repo-test-kit/**'
- exclude '**/modules/spatial/**'
- exclude '**/modules/transform/**'
- exclude '**/modules/unsigned-long/**'
- exclude '**/modules/vector-tile/**'
- exclude '**/modules/vectors/**'
- exclude '**/modules/wildcard/**'
- exclude '**/modules/x-pack-*/**'
- includeEmptyDirs = false
- }
-
- into("${archiveDir}/conf/") {
- from file('src/main/assembly/conf/sonar.properties')
- filter(ReplaceTokens, tokens: [
- 'searchDefaultHeapSize': '512MB',
- 'searchJavaOpts' : '-Xmx512m -Xms512m -XX:MaxDirectMemorySize=256m -XX:+HeapDumpOnOutOfMemoryError',
- 'ceDefaultHeapSize' : '512MB',
- 'ceJavaOpts' : '-Xmx512m -Xms128m -XX:+HeapDumpOnOutOfMemoryError',
- 'webDefaultHeapSize' : '512MB',
- 'webJavaOpts' : '-Xmx512m -Xms128m -XX:+HeapDumpOnOutOfMemoryError'
- ])
- }
-
- into("${archiveDir}/bin/linux-x86-64/") {
- from file('src/main/assembly/bin/linux-x86-64/sonar.sh')
- filter(ReplaceTokens, tokens: [
- 'sqversion': version
- ])
- }
-
- into("${archiveDir}/bin/macosx-universal-64/") {
- from file('src/main/assembly/bin/macosx-universal-64/sonar.sh')
- filter(ReplaceTokens, tokens: [
- 'sqversion': version
- ])
- }
-
- into("${archiveDir}/bin/windows-x86-64/") {
- from file('src/main/assembly/bin/windows-x86-64/StartSonar.bat')
- filter(ReplaceTokens, tokens: [
- 'sqversion': version
- ])
- }
-
- into("${archiveDir}/bin/windows-x86-64/lib/") {
- from file('src/main/assembly/bin/windows-x86-64/lib/SonarServiceWrapperTemplate.xml')
- filter(ReplaceTokens, tokens: [
- 'sqversion': version
- ])
- }
-
- into("${archiveDir}/elasticsearch/") {
- from file('src/main/assembly/elasticsearch-patch')
- include 'bin/elasticsearch'
- }
- // Create the empty dir (plugins) required by elasticsearch
- into("${archiveDir}/elasticsearch/") {
- from "$buildDir/elasticsearch"
- }
- into("${archiveDir}/lib/extensions/") {
- from configurations.bundledPlugin
- }
- into("${archiveDir}/lib/scanner/") {
- from configurations.scanner
- }
- into("${archiveDir}/lib/") {
- from shadowJar
- }
- into("${archiveDir}/web/") {
- duplicatesStrategy DuplicatesStrategy.FAIL
- // FIXME use configurations.web with correct artifacts
- from(tasks.getByPath(':server:sonar-web:yarn_run').outputs) { a ->
- if (official) {
- project(':private:branding').fileTree('src').visit { b ->
- if (!b.isDirectory()) {
- a.exclude b.relativePath.toString()
- }
- }
- }
- }
- if (official) {
- from project(':private:branding').file('src')
- }
- }
- into("${archiveDir}/lib/jdbc/mssql/") {
- from configurations.jdbc_mssql
- }
- into("${archiveDir}/lib/jdbc/postgresql/") {
- from configurations.jdbc_postgresql
- }
- into("${archiveDir}/lib/jdbc/h2/") {
- from configurations.jdbc_h2
- }
- into("${archiveDir}/lib/") {
- from configurations.shutdowner
- }
- }
- // Create the empty dir required by elasticsearch
- zip.doFirst {
- new File(buildDir, 'elasticsearch/plugins').mkdirs()
- }
- // Check the size of the archive
- zip.doLast {
- def minLength = 272000000
- def maxLength = 297000000
-
- def length = archiveFile.get().asFile.length()
- if (length < minLength)
- throw new GradleException("${archiveFileName.get()} size ($length) too small. Min is $minLength")
- if (length > maxLength)
- throw new GradleException("${destinationDirectory.get()}/${archiveFileName.get()} size ($length) too large. Max is $maxLength")
- }
- assemble.dependsOn zip
-
- // the script start.sh unpacks OSS distribution into $buildDir/distributions/sonarqube-oss.
- // This directory should be deleted when the zip is changed.
- task cleanLocalUnzippedDir(dependsOn: zip) {
- def unzippedDir = file("$buildDir/distributions/sonarqube-$version")
- inputs.files(file("$buildDir/distributions/sonar-application-${version}.zip"))
- outputs.upToDateWhen { true }
-
- doLast {
- println("delete directory ${unzippedDir}")
- project.delete(unzippedDir)
- }
- }
- assemble.dependsOn cleanLocalUnzippedDir
-
- artifacts { zip zip }
-
- artifactoryPublish.skip = false
-
- def bomFile = layout.buildDirectory.file('reports/bom.json')
- cyclonedxBom {
- includeConfigs += ["runtimeClasspath", "web", "shutdowner", "jdbc_mssql", "jdbc_postgresql", "jdbc_h2", "bundledPlugin_deps",
- "cyclonedx"]
- outputs.file bomFile
- }
- tasks.cyclonedxBom {
- inputs.files(configurations.runtimeClasspath, configurations.shutdowner, configurations.jdbc_mssql,
- configurations.jdbc_postgresql, configurations.jdbc_h2, configurations.bundledPlugin_deps, configurations.cyclonedx)
- }
- def bomArtifact = artifacts.add('archives', bomFile.get().asFile) {
- type 'json'
- classifier 'cyclonedx'
- builtBy 'cyclonedxBom'
- }
-
- publishing {
- publications {
- mavenJava(MavenPublication) {
- artifact zip
- }
- if (enableBom) {
- mavenJava(MavenPublication) {
- artifact bomArtifact
- }
- }
- }
- }
|