sonarqube {
  properties {
    property 'sonar.projectName', "${projectTitle} :: DAO"
  }
}

dependencies {
  // please keep the list grouped by configuration and ordered by name

  compile 'com.google.guava:guava'
  compile 'com.google.protobuf:protobuf-java'
  compile 'commons-io:commons-io'
  compile 'commons-lang:commons-lang'
  compile 'net.jpountz.lz4:lz4'
  compile 'org.mybatis:mybatis'
  compile 'org.sonarsource.api.plugin:sonar-plugin-api'

  compile project(':server:sonar-db-core')
  compile project(':server:sonar-db-migration')
  compile project(':sonar-core')

  compileOnly 'com.google.code.findbugs:jsr305'

  testCompile 'com.tngtech.java:junit-dataprovider'
  testCompile 'commons-dbutils:commons-dbutils'
  testCompile 'junit:junit'
  testCompile 'org.assertj:assertj-core'
  testCompile 'org.assertj:assertj-guava'
  testCompile 'org.mockito:mockito-core'
  testCompile 'org.sonarsource.orchestrator:sonar-orchestrator'
  testCompile project(':sonar-testing-harness')
  testCompile project(':sonar-plugin-api-impl')

  testCompileOnly 'com.google.code.findbugs:jsr305'

  testRuntime 'com.h2database:h2'
  testRuntime 'com.microsoft.sqlserver:mssql-jdbc'
  testRuntime 'com.oracle.database.jdbc:ojdbc8'
  testRuntime 'org.postgresql:postgresql'

  testFixturesApi testFixtures(project(':server:sonar-db-core'))

  testFixturesImplementation 'com.h2database:h2'

  testFixturesCompileOnly 'com.google.code.findbugs:jsr305'
}

test {
  systemProperty 'orchestrator.configUrl', System.getProperty('orchestrator.configUrl')
}

task dumpSchema(type:JavaExec) {
    mainClass = 'org.sonar.db.dump.DumpSQSchema'
    classpath = sourceSets.test.runtimeClasspath
}
tasks.check.dependsOn dumpSchema

task createDB(type:JavaExec) {
    mainClass = 'org.sonar.db.createdb.CreateDb'
    classpath = sourceSets.test.runtimeClasspath
    systemProperty 'orchestrator.configUrl', System.getProperty('orchestrator.configUrl')
    if (!project.version.endsWith("-SNAPSHOT")) {
        systemProperty 'sonar.runtimeVersion', project.version
    }
}

task testJar(type: Jar) {
  archiveClassifier = 'tests'
  from sourceSets.test.output
}

configurations {
  tests
}

artifacts {
   tests testJar
}

jar {
    // remove exclusion on proto files so that they can be included by other modules
    setExcludes([])
}