sonarqube {
  properties {
    property 'sonar.projectName', "${projectTitle} :: Core"
  }
}

configurations {
  includeInResources
}

dependencies {
  // please keep list ordered

  compile 'ch.qos.logback:logback-classic'
  compile 'ch.qos.logback:logback-core'
  compile 'com.google.protobuf:protobuf-java'
  compile 'commons-codec:commons-codec'
  compile 'org.apache.commons:commons-csv'
  compile 'org.codehaus.sonar:sonar-classloader'
  compile 'org.picocontainer:picocontainer'
  compile 'org.slf4j:slf4j-api'
  compile 'org.sonarsource.update-center:sonar-update-center-common'
  compile 'org.mindrot:jbcrypt'
  compile project(path: ':sonar-plugin-api', configuration: 'shadow')

  compileOnly 'com.google.code.findbugs:jsr305'

  includeInResources project(path: ':sonar-plugin-api-deps', configuration: 'shadow')

  testCompile 'com.tngtech.java:junit-dataprovider'
  testCompile 'junit:junit'
  testCompile 'org.assertj:assertj-core'
  testCompile 'org.mockito:mockito-core'
  testCompile 'org.simpleframework:simple'
  testCompile project(':sonar-testing-harness')

  testCompileOnly 'com.google.code.findbugs:jsr305'
}

// sonar-plugin-api.jar is copied into target JAR file
processResources {
  into('/') {
    from configurations.includeInResources
    rename '(.*)-' + project.version + '-all.jar', '$1.jar'
  }
}

// Used by sonar-db-core to run DB Unit Tests
artifactoryPublish.skip = false
publishing {
  publications {
    mavenJava(MavenPublication) {
      from components.java
      if (release) {
        artifact sourcesJar
        artifact javadocJar
      }
    }
  }
}