docs/sandbox/common/tracing/TraceJoinPointsBase.java


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

// START-SAMPLE tracing-traceJoinPoints Trace join points executed   
/* TraceJoinPointsBase.java */

package tracing;

import org.aspectj.lang.JoinPoint;

/**
 * Trace join points being executed in context.
 * To use this, define the abstract members in a subaspect.
 * <b>Warning</b>: this does not trace join points that do not
 * support after advice.
 * @author Jim Hugunin, Wes Isberg
 */
abstract aspect TraceJoinPointsBase {
    // this line is for AspectJ 1.1
    // for Aspectj 1.0, use "TraceJoinPointsBase dominates * {"
    declare precedence : TraceJoinPointsBase, *;

    abstract protected pointcut entry();

    protected pointcut exit(): call(* java..*.*(..));

    final pointcut start(): entry() && !cflowbelow(entry());

    final pointcut trace(): cflow(entry()) 
        && !cflowbelow(exit()) && !within(TraceJoinPointsBase+);

    private pointcut supportsAfterAdvice() : !handler(*)
        && !preinitialization(new(..));

    before(): start() { startLog(); }

    before(): trace() && supportsAfterAdvice(){ 
        logEnter(thisJoinPointStaticPart); 
    }

    after(): trace() && supportsAfterAdvice() { 
        logExit(thisJoinPointStaticPart); 
    }

    after(): start() { completeLog(); }
    
    abstract protected void logEnter(JoinPoint.StaticPart jp);
    abstract protected void logExit(JoinPoint.StaticPart jp);
    abstract protected void startLog();
    abstract protected void completeLog();
}

// END-SAMPLE tracing-traceJoinPoints